extra/cairo-perl/PKGBUILD

pkgname=cairo-perl
pkgver=1.106
pkgrel=2
pkgdesc="Perl wrappers for cairo"
arch=(i386 amd64)
license=('LGPL')
url="http://gtk2-perl.sourceforge.net/"
options=('!emptydirs')
depends=('cairo' 'perl')
makedepends=('perl-extutils-depends' 'perl-extutils-pkgconfig')
source=(http://downloads.sourceforge.net/sourceforge/gtk2-perl/Cairo-${pkgver}.tar.gz)
md5sums=('47ca0ae0f5b9bc4c16a27627ff48bd8b')

build() {
  cd "${srcdir}/Cairo-${pkgver}"
  perl Makefile.PL INSTALLDIRS=vendor
  make
}

check() {
  cd "${srcdir}/Cairo-${pkgver}"
  make test
}

package() {
  cd "${srcdir}/Cairo-${pkgver}"
  make DESTDIR="${pkgdir}" install

# template start; name=perl-binary-module-dependency; version=1;
if [[ $(find "$pkgdir/usr/lib/perl5/" -name "*.so") ]]; then
	_perlver_min=$(perl -e '$v = $^V->{version}; print $v->[0].".".($v->[1]);')
	_perlver_max=$(perl -e '$v = $^V->{version}; print $v->[0].".".($v->[1]+1);')
	depends+=("perl>=$_perlver_min" "perl<$_perlver_max")
fi
# template end;
}